blob: a3d1d9b38d79a4cdcbd101fb17ce01f795c3dadc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
|
cmake_minimum_required (VERSION 3.9)
project (Lagrange
VERSION 1.0.0
DESCRIPTION "Beautiful Gemini Client"
LANGUAGES C
)
set (COPYRIGHT_YEAR 2020)
include (Embed.cmake)
find_package (the_Foundation REQUIRED)
find_package (PkgConfig REQUIRED)
pkg_check_modules (SDL2 REQUIRED sdl2)
# Embedded resources are written to a generated source file.
message (STATUS "Preparing embedded resources...")
set (EMBED_RESOURCES
res/FiraSans-Regular.ttf
res/FiraSans-LightItalic.ttf
res/FiraMono-Regular.ttf
)
# if (UNIX AND NOT APPLE)
# list (APPEND EMBED_RESOURCES res/appicon-64.png)
# endif ()
embed_make (${EMBED_RESOURCES})
# Source files.
set (SOURCES
${CMAKE_CURRENT_BINARY_DIR}/embedded.c
${CMAKE_CURRENT_BINARY_DIR}/embedded.h
src/main.c
src/app.c
src/app.h
src/stb_image.h
src/stb_truetype.h
# User interface:
src/ui/color.c
src/ui/color.h
src/ui/command.c
src/ui/command.h
src/ui/documentwidget.h
src/ui/documentwidget.c
src/ui/metrics.c
src/ui/metrics.h
src/ui/paint.c
src/ui/paint.h
src/ui/text.c
src/ui/text.h
src/ui/util.c
src/ui/util.h
src/ui/window.c
src/ui/window.h
# Widgets:
src/ui/widget.c
src/ui/widget.h
src/ui/inputwidget.c
src/ui/inputwidget.h
src/ui/labelwidget.c
src/ui/labelwidget.h
)
if (IOS)
elseif (APPLE)
list (APPEND SOURCES src/ui/macos.m src/ui/macos.h)
# list (APPEND RESOURCES
# "res/Lagrange.icns"
# )
endif ()
if (MSYS)
set (WINRC_FILE_VERSION ${PROJECT_VERSION_MAJOR},${PROJECT_VERSION_MINOR},${PROJECT_VERSION_PATCH},0)
set (WINRC_PRODUCT_VERSION ${PROJECT_VERSION_MAJOR},${PROJECT_VERSION_MINOR},0,0)
configure_file (res/lagrange.rc.in ${CMAKE_CURRENT_BINARY_DIR}/lagrange.rc NEWLINE_STYLE WIN32)
list (APPEND SOURCES src/win32.c src/win32.h ${CMAKE_CURRENT_BINARY_DIR}/lagrange.rc)
endif ()
set_source_files_properties (${RESOURCES} PROPERTIES MACOSX_PACKAGE_LOCATION Resources)
# Target.
add_executable (app ${SOURCES} ${RESOURCES})
set_target_properties (app PROPERTIES OUTPUT_NAME lagrange)
target_include_directories (app PUBLIC
src
${CMAKE_CURRENT_BINARY_DIR}
${SDL2_INCLUDE_DIRS}
)
target_compile_options (app PUBLIC
-Werror=implicit-function-declaration
${SDL2_CFLAGS}
)
target_compile_definitions (app PUBLIC LAGRANGE_APP_VERSION="${PROJECT_VERSION}")
target_link_libraries (app PUBLIC the_Foundation::the_Foundation)
target_link_libraries (app PUBLIC ${SDL2_LDFLAGS})
if (APPLE)
if (IOS)
target_link_libraries (app PUBLIC "-framework UIKit")
else ()
target_link_libraries (app PUBLIC "-framework AppKit")
endif ()
set_target_properties (app PROPERTIES
OUTPUT_NAME "Lagrange"
MACOSX_BUNDLE YES
MACOSX_BUNDLE_INFO_PLIST "${CMAKE_CURRENT_LIST_DIR}/res/MacOSXBundleInfo.plist.in"
MACOSX_BUNDLE_BUNDLE_NAME "Lagrange"
MACOSX_BUNDLE_INFO_STRING "${PROJECT_VERSION}"
MACOSX_BUNDLE_ICON_FILE "Lagrange.icns"
MACOSX_BUNDLE_BUNDLE_VERSION "${PROJECT_VERSION}"
MACOSX_BUNDLE_LONG_VERSION_STRING "${PROJECT_VERSION}"
MACOSX_BUNDLE_SHORT_VERSION_STRING "${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}"
MACOSX_BUNDLE_GUI_IDENTIFIER "fi.skyjake.Lagrange"
MACOSX_BUNDLE_COPYRIGHT "© ${COPYRIGHT_YEAR} Jaakko Keränen"
)
endif ()
if (UNIX)
target_link_libraries (app PUBLIC m)
endif ()
# Deployment.
if (MSYS)
install (TARGETS app DESTINATION .)
install (PROGRAMS
${SDL2_LIBDIR}/SDL2.dll
$<TARGET_FILE:the_Foundation::the_Foundation>
DESTINATION .
)
elseif (UNIX AND NOT APPLE)
set_target_properties (app PROPERTIES
INSTALL_RPATH_USE_LINK_PATH YES
)
set (desktop ${CMAKE_CURRENT_BINARY_DIR}/fi.skyjake.lagrange.desktop)
file (WRITE ${desktop} "[Desktop Entry]
Name=Lagrange
Comment=${PROJECT_DESCRIPTION}
;Categories=
Exec=${CMAKE_INSTALL_PREFIX}/bin/lagrange
Terminal=false
Type=Application
Icon=fi.skyjake.lagrange")
install (TARGETS app DESTINATION bin)
install (FILES ${desktop} DESTINATION share/applications)
# install (FILES res/appicon-128.png
# DESTINATION share/icons/hicolor/256x256/apps
# RENAME fi.skyjake.lagrange.png
# )
endif ()
|
